:- module(_,_).

% - Recursive sum of a list:

sum([], 0).
sum([N|Ns], Sum) :-
    sum(Ns, Inter),
    Sum is Inter + N.

% - Iterative version (tail recursive, using an accumulator):

sum_iter(L, Res) :-
    sum_acc(L, 0, Res).

sum_acc([], Res, Res).
sum_acc([N|Ns], In, Out) :-
    Inter is In + N,
    sum_acc(Ns, Inter, Out).

%   Try:
% ?- sum([1,2,3],S).
% ?- sum_iter([1,2,3],S).

% - The speedup, with a list of `N` elements:

test(N) :-
    numbers(N, L),
    speedup(sum(L,_), sum_iter(L,_)).

% ?- test(100000).

numbers(0, []).
numbers(N, [N|Ns]) :-
    N > 0,
    N1 is N - 1,
    numbers(N1, Ns).

% - `speedup/2` runs the two goals and compares their times, as in
%   the first example (`010_swap.pl`).

%! \begin{hide}
speedup(Slow, Fast) :-
    speedup_loop(true, Slow, Fast).

speedup_loop(Loop, Slow, Fast) :-
    time_of(Loop, Slow, TS),
    time_of(Loop, Fast, TF),
    show_speedup(TS, TF).

time_of(Loop, Goal, T) :-
    repeat_time(1, Loop, Goal, T).

repeat_time(N, Loop, Goal, T) :-
    loop_time(N, Goal, TG),
    (   TG >= 100
    ->  loop_time(N, Loop, TL),
        (   TG - TL > TG / 10        % (else too fast to tell
        ->  T is (TG - TL) / N       %  from the loop itself)
        ;   T = 0
        )
    ;   N1 is N * 10,
        repeat_time(N1, Loop, Goal, T)
    ).

loop_time(N, Goal, T) :-
    statistics(runtime, [T0, _]),
    ( between(1, N, _), once(Goal), fail ; true ),
    statistics(runtime, [T1, _]),
    T is T1 - T0.

show_speedup(TS, TF) :-
    format("Slow: ", []), show_time(TS),
    format(", fast: ", []), show_time(TF),
    (   TS > 0, TF > 0
    ->  S is TS / TF,
        format(", speedup: ~1f~n", [S])
    ;   nl
    ).

show_time(T) :-
    T > 0, !,
    format("~4f ms", [T]).
show_time(_) :-
    format("too fast to measure", []).

:- use_module(library(between)).
%! \end{hide}