:- module(_,_).

% - Value greater than all elements in list, without using indexing:

bad_greater(_X,[]).
bad_greater(X,[Y|Ys]) :- X > Y, bad_greater(X,Ys).

% - Same, making use of first-argument indexing:

good_greater([],_X).
good_greater([Y|Ys],X) :- X > Y, good_greater(Ys,X).

%   Try:
% ?- bad_greater(5,[1,2,3]).
% ?- good_greater([1,2,3],5).

% - The speedup, with a list of `N` elements:

test(N) :-
    numbers(N, L),
    X is N + 1,
    speedup(bad_greater(X,L), good_greater(L,X)).

% ?- test(600000).

numbers(0, []).
numbers(N, [N|Ns]) :-
    N > 0,
    N1 is N - 1,
    numbers(N1, Ns).

% - `speedup/2` runs the two goals and compares their times, as in
%   the first example (`010_swap.pl`).

%! \begin{hide}
speedup(Slow, Fast) :-
    speedup_loop(true, Slow, Fast).

speedup_loop(Loop, Slow, Fast) :-
    time_of(Loop, Slow, TS),
    time_of(Loop, Fast, TF),
    show_speedup(TS, TF).

time_of(Loop, Goal, T) :-
    repeat_time(1, Loop, Goal, T).

repeat_time(N, Loop, Goal, T) :-
    loop_time(N, Goal, TG),
    (   TG >= 100
    ->  loop_time(N, Loop, TL),
        (   TG - TL > TG / 10        % (else too fast to tell
        ->  T is (TG - TL) / N       %  from the loop itself)
        ;   T = 0
        )
    ;   N1 is N * 10,
        repeat_time(N1, Loop, Goal, T)
    ).

loop_time(N, Goal, T) :-
    statistics(runtime, [T0, _]),
    ( between(1, N, _), once(Goal), fail ; true ),
    statistics(runtime, [T1, _]),
    T is T1 - T0.

show_speedup(TS, TF) :-
    format("Slow: ", []), show_time(TS),
    format(", fast: ", []), show_time(TF),
    (   TS > 0, TF > 0
    ->  S is TS / TF,
        format(", speedup: ~1f~n", [S])
    ;   nl
    ).

show_time(T) :-
    T > 0, !,
    format("~4f ms", [T]).
show_time(_) :-
    format("too fast to measure", []).

:- use_module(library(between)).
%! \end{hide}