:- module(_,_).
:- use_module(library(between)).

% - Do not keep alternatives if they are not needed:

member_check([X|_],X) :- !.
member_check([_|Xs],X) :- member_check(Xs,X).

%   Try (asking for more solutions):
% ?- member(b,[a,b,c,b]).
% ?- member_check([a,b,c,b],b).

% - Program deterministic problems in a deterministic way:

decomp_simplistic(N, S1, S2) :-
    between(0, N, S1),
    between(0, N, S2),
    N =:= S1 + S2.

decomp(N, S1, S2) :-
    between(0, N, S1),
    S2 is N - S1.

%   Try (asking for more solutions):
% ?- decomp_simplistic(3,S1,S2).
% ?- decomp(3,S1,S2).

% - The speedup, finding all the solutions (it grows with `N`):

all(Goal) :-
    call(Goal),
    fail.
all(_).

% ?- speedup(all(decomp_simplistic(1000,_,_)), all(decomp(1000,_,_))).
% ?- speedup(all(decomp_simplistic(3000,_,_)), all(decomp(3000,_,_))).

% - `speedup/2` runs the two goals and compares their times, as in
%   the first example (`010_swap.pl`).

%! \begin{hide}
speedup(Slow, Fast) :-
    speedup_loop(true, Slow, Fast).

speedup_loop(Loop, Slow, Fast) :-
    time_of(Loop, Slow, TS),
    time_of(Loop, Fast, TF),
    show_speedup(TS, TF).

time_of(Loop, Goal, T) :-
    repeat_time(1, Loop, Goal, T).

repeat_time(N, Loop, Goal, T) :-
    loop_time(N, Goal, TG),
    (   TG >= 100
    ->  loop_time(N, Loop, TL),
        (   TG - TL > TG / 10        % (else too fast to tell
        ->  T is (TG - TL) / N       %  from the loop itself)
        ;   T = 0
        )
    ;   N1 is N * 10,
        repeat_time(N1, Loop, Goal, T)
    ).

loop_time(N, Goal, T) :-
    statistics(runtime, [T0, _]),
    ( between(1, N, _), once(Goal), fail ; true ),
    statistics(runtime, [T1, _]),
    T is T1 - T0.

show_speedup(TS, TF) :-
    format("Slow: ", []), show_time(TS),
    format(", fast: ", []), show_time(TF),
    (   TS > 0, TF > 0
    ->  S is TS / TF,
        format(", speedup: ~1f~n", [S])
    ;   nl
    ).

show_time(T) :-
    T > 0, !,
    format("~4f ms", [T]).
show_time(_) :-
    format("too fast to measure", []).

:- use_module(library(between)).
%! \end{hide}